Tableau Prep-Hilfe

1. Um diese Frage in Tableau Desktop zu beantworten, verwenden wir die Funktion DATEDIFF. Diese Funktion nutzt drei Argumente in Form des Datumsteils, des Startdatums und des Enddatums. Da wir wissen möchten, wie viele Tage zwischen diesen Ereignissen liegen, verwenden wir die Datumskomponente 'day'. Das Start- und Enddatum im Datensatz lautet Datum des 1. Verstoßes und Datum des 2. Verstoßes.

2. Die Berechnung lautet:

   Zeit zwischen Verstößen = DATEDIFF('day', [1st Infraction Date], [2nd Infraction Date])

3. Daraus können wir eine Darstellung anhand der Fahrer-ID als Balkendiagramm erstellen. Beachten Sie, dass für sieben Fahrer kein zweiter Verstoß vorlag. Demzufolge sind sieben Nullen vorhanden.

   

1. Um diese Frage in Tableau Desktop zu beantworten, erstellen wir ein Streudiagramm für das 1. Bußgeld und 2. Bußgeld. Durch das Verschieben der Fahrer-ID in den Container Detail auf der Karte Markierungen können wir für jeden Fahrer eine Markierung erstellen.

2. Wenn Sie eine Trendlinie hinzufügen möchten, verwenden Sie die Registerkarte Analysen im linken Bereich, und stellen Sie eine lineare Trendlinie dar. Beim Zeigen mit der Maus auf die Trendlinie sehen wir, dass der Bestimmtheitsmaßwert praktisch null ist und dass der p-Wert weit über der signifikanten Obergrenze liegt. Wir stellen fest, dass zwischen dem ersten und zweiten Bußgeld keine Korrelation existiert.

   Bei der Verwendung dieses Streudiagramms in einem Dashboard sollte die Trendlinie entfernt werden.

Wenn wir die Analyse detaillierter betrachten möchten, müssen wir möglicherweise einige Berechnungen anstellen.

1. Um diese Frage in Tableau Desktop zu beantworten, müssen wir die Bußgelder für beide Verstöße in einem einzelnen Feld hinzufügen. Da für einige Fahrer möglicherweise kein zweiter Verstoß vorliegt, müssen wir die Null-Null-Funktion ZN verwenden, um jegliche Nullen für das 2. Bußgeld in Nullwerte zu konvertieren. Andernfalls führt dies zu Nullen, wenn es keine zweite Geldstrafe gibt.

2. Die Berechnung lautet:

   Bezahlter Gesamtbetrag = [1st Fine Amount] + ZN([2nd Fine Amount])

3. Wir können den Wert für Bezahlter Gesamtbetrag anhand der Fahrer-ID darstellen und das Balkendiagramm sortieren.

1. Um diese Frage in Tableau Desktop zu beantworten, müssen wir eine raffiniertere Berechnung vom Typ IF ausführen, um zu vergleichen, ob die Typen des ersten und zweiten Verstoßes identisch sind. Ist dies der Fall, weisen wir den Wert "1" zu. Wenn sie nicht identisch sind, weisen wir den Wert "2" zu. Da uns nur Typen mit mehreren Verstößen wichtig sind, wird jedem anderen Ergebnis, z. B. einem zweiten Verstoßtyp mit dem Wert null, der Wert "1" zugewiesen.

2. Die Berechnung lautet:

   Anzahl Verstoßtypen =

   IF [1st Infraction Type]=[2nd Infraction Type] THEN 1 
   ELSEIF [1st Infraction Type]!= [2nd Infraction Type] THEN 2 
   ELSE 1 END

3. Wir können den Wert für Anzahl Verstoßtypen anhand der Fahrer-ID darstellen und das Balkendiagramm sortieren.

1. Um diese Frage in Tableau Desktop zu beantworten, reicht es nicht aus, den Bußgeld-Gesamtbetrag einfach durch zwei zu teilen, da einige Fahrer nur einen Verstoß begangen haben. Wir können auch nicht das durchschnittliche Bußgeld pro Fahrer berechnen und den Durchschnitt dieser Werte verwenden, weil die Durchschnittsbestimmung von Durchschnittswerten zu Inkonsistenzen führen kann. Stattdessen müssen wir den bezahlten Gesamtbetrag von Fahrern berechnen, die nie eine Verkehrsschule besucht haben. Anschließend teilen wir diesen Wert durch die Gesamtzahl Verstöße, die mit diesen Bußgeldern in Verbindung steht.

   1. Zuerst müssen wir bestimmen, ob für die einzelnen Fahrer ein zweiter Verstoß vorliegt. Dabei können wir auf die Tatsache zurückgreifen, dass die Informationen in allen "2." Feldern null sind, wenn kein zweiter Verstoß vorliegt, und wir können mit der Erstellung der Berechnung beginnen.

      IFNULL([2nd Infraction Type], 'no')

      Dies gibt entweder einen Verstoßtyp (sofern vorhanden) oder "nein" zurück, wenn kein zweiter Verstoß vorlag.

   2. Als Nächstes müssen wir diese Information in die Anzahl Verstöße (1 oder 2) konvertieren. Wenn das Ergebnis unserer Berechnung vom Typ IFNULL "nein" lautet, sollte der Fahrer mit einem Bußgeld markiert werden. Alle anderen Ergebnisse sollen mit zwei Bußgeldern markiert werden. Die Berechnung lautet:

      Anzahl Verstöße =

      IF IFNULL([2nd Infraction Type], 'no') = 'no' THEN 1 
      ELSE 2 
      END

   3. Nun müssen wir den Bußgeld-Gesamtwert betrachten. Ähnlich wie bei Frage 3 oben fügen wir die ersten und zweiten Bußgeldbeträge hinzu und schließen den zweiten Betrag in eine ZN-Funktion ein. Da diese Berechnung jedoch auf Ebene des gesamten Datensatzes erfolgen soll, hat es sich bewährt, die Aggregationen, SUM, in der Berechnung selbst anzugeben. Die Berechnung lautet: 

      SUM([1st Fine Amount]) + SUM( ZN([2nd Fine Amount]) )

   4. Um es auf den Punkt zu bringen, teilen wir diesen Bußgeld-Gesamtwert durch unser neues Feld Anzahl Verstöße, um den durchschnittlichen Bußgeldbetrag zu ermitteln:

      Durchschnittliches Bußgeld = ( SUM([1st Fine Amount]) + SUM( ZN([2nd Fine Amount]) ) ) / SUM([Number of Infractions])

2. Wir müssen noch die Fahrer herausfiltern, die je eine Verkehrsschule besucht haben. Diese Informationen werden jedoch auch in zwei Feldern gespeichert.

   1. Tableau ist hinsichtlich numerischer Berechnungen sehr effizient. Wir drücken dies in Zahlen aus, um eine möglichst gute Leistung zu erzielen. Um diese beiden Felder zu kombinieren, erstellen wir für jedes eine Berechnung mit der Aussage "Ja = 1" und "Nein = 0" (null ist ebenfalls = 0 für Fahrer ohne zweiten Verstoß). Durch die Summierung der Ergebnisse dieser Berechnungen wird deutlich, dass ein Fahrer mit dem Gesamtwert 0 nie eine Verkehrsschule besucht hat (während der Wert 1 oder 2 angibt, wie oft ein Fahrer teilgenommen hat). Anschließend können wir die Ergebnisse filtern, um nur Fahrer mit dem Wert 0 beizubehalten.

   2. Zu diesem Zeitpunkt verwenden wir eine Anweisung vom Typ CASE anstatt IF. Ihre Funktion ist sehr ähnlich, sie unterscheidet sich jedoch in ihrer Syntax. Der Beginn der Berechnung sollte wie folgt aussehen:

      CASE [1st Traffic School]
      WHEN 'Yes' THEN 1
      WHEN 'No' THEN 
      ELSE 0
      END

   3. Anschließend tun wir dasselbe für die 2. Verkehrsschule. Wir können beide Komponenten in dieselbe Berechnung einfließen lassen, indem wir jede CASE-Anweisung in Klammern einschließen und zwischen ihnen ein Plus hinzufügen. Wenn wir einige der Zeilenumbrüche entfernen, sieht die Berechnung wie folgt aus:

      Anzahl Besuche einer Verkehrsschule =

      (CASE [1st Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)
      +
      (CASE [2nd Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)
      

   4. Wenn wir die Anzahl der Besuche einer Verkehrsschule in den Bereich "Dimensionen" des Bereichs Daten ziehen (über der Linie), werden die Werte 0–2 diskret.

   5. Wenn wir nun nach der Anzahl Besuche einer Verkehrsschule filtern, können wir einfach die 0 auswählen und sicher sein, dass wir die Fahrer erhalten, die nie eine Verkehrsschule besucht haben.

3. Um die ursprüngliche Frage zu beantworten, verschieben wir Durchschnittliches Bußgeld in den Container Text auf der Karte Markierungen.

   Da wir die Aggregationen in die Berechnungen integriert haben, lautet die Aggregation im Feld AGG. Sie lässt sich nicht ändern. Dies entspricht den Erwartungen.

1. Um diese Frage in Tableau Desktop zu beantworten, verwenden wir wie bei der ersten Frage auch die Funktion DATEDIFF . Für diese Funktion sind ein Start- und Enddatum erforderlich. Diese Informationen sind zwar in unseren Daten vorhanden, sie befinden sich jedoch alle in einem Feld. Wir müssen sie herausziehen und in zwei Feldern anordnen.

   1. Erstellen Sie zwei vorläufige berechnete Felder:

      1. Verstoßdatum = IF [Infraction Number] = "1st" THEN [Infraction Date] END

      2. Verstoßdatum = IF [Infraction Number] = "2nd" THEN [Infraction Date] END

   2. Da wir sicherstellen möchten, dass beide Werte für den Vergleich der einzelne Fahrer zur Verfügung stehen, müssen wir sie auf der Ebene der Fahrer-ID korrigieren.

      Hinweis: Sie glauben mir nicht? Führen Sie eine Berechnung vom Typ DATEDIFF durch, und lassen Sie diese beiden Felder dabei unverändert: Zeit zwischen Verstößen = DATEDIFF('day', [1st Infraction Date], [2nd Infraction Date])
      Sie erhalten überall Null-Ergebnisse, da Tableau versucht, in einer Datenstruktur einen Vergleich vorzunehmen, der wie folgt aussieht:
      
      Hier kennt die Zeile, die das erste Datum kennt, nicht das zweite Datum und umgekehrt. Um dies zu umgehen, verwenden wir einen LOD-Ausdruck vom Typ FIXED, um diese erste und zweite Datumsangabe nach Fahrer-ID in Verbindung zu bringen.

   Bearbeiten Sie die Berechnung wie folgt:

   1. Verstoßdatum = { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "1st" THEN [Infraction Date] END ) }

   2. Verstoßdatum = { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "2nd" THEN [Infraction Date] END ) }

   Hinweis: Beim Einbetten in einen LOD-Ausdruck muss die ursprüngliche IF-Berechnung aggregiert werden. Es kann eine beliebige einfache Aggregation verwendet werden, bei der der Datenwert erhalten bleibt (Aggregationen wie SUM, AVG oder MIN funktionieren, CNT oder CNTD jedoch nicht).

   Hinweis: Diese Berechnungen können auch in Tableau Prep Builder erstellt werden. Weitere Informationen zu LOD-Ausdrücken in Prep finden Sie unter Erstellen von Detailgenauigkeits-, Rang- und Kachelberechnungen.

   3. Nun können wir die Berechnung DATEDIFF wie folgt erstellen:

      Zeit zwischen Verstößen = DATEDIFF('day', [1st Infraction Date], [2nd Infraction Date])

      • Wenn Sie Wochen oder Monate untersuchen möchten, ändern Sie einfach die Datumskomponente (momentan 'day').

      • Es wäre auch möglich, eine einzelne Berechnung für alles zu erstellen, indem Sie die FIXED-Berechnungen direkt unter DATEDIFF platzieren: 

        DATEDIFF ( 'day', 
        { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "1st" THEN [Infraction Date] END ) },
        { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "2nd" THEN [Infraction Date] END ) }
        )

   4. Stellen Sie Zeit zwischen Verstößen in Spalten und die Fahrer-ID in Zeilen dar.

Die Ergebnisse sind identisch mit der Ausgabe mit der nicht pivotierten Datenstruktur.

1. Um diese Frage in Tableau Desktop zu beantworten, verwenden wir eine sehr ähnliche Logik wie bei der vorherigen Frage. Mithilfe der Verstoßnummer bestimmen wir, ob es sich bei einer bestimmten Zeile um den ersten oder zweiten Verstoß handelt. Dann entnehmen wir den Bußgeldbetrag entsprechend.

   1. Wenn lediglich ein Streudiagramm erstellt werden soll, können wir den LOD-Teil überspringen und lediglich die Berechnung IF verwenden:

      1. Bußgeld = IF [Infraction Number] = "1st" THEN [Fine Amount] END

      2. Bußgeld = IF [Infraction Number] = "2nd" THEN [Fine Amount] END

   2. Wenn Sie jedoch den Betrag für das erste und zweite Bußgeld für einen einzelnen Fahrer vergleichen und den Unterschied anzeigen möchten, stehen wir vor demselben Null-Problem wie bei den Datumsangaben. Es kann nicht schaden, diese Berechnungen in einen LOD-Ausdruck vom Typ FIXED einzuschließen. Daher ist es eine gute Ideen, dies von vornherein zu tun:

      1. Bußgeld = { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "1st" THEN [Fine Amount] END ) }

      2. Bußgeld = { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "2nd" THEN [Fine Amount] END ) }

      Diese Berechnungen können auch in Tableau Prep Builder erstellt werden. Weitere Informationen zu LOD-Ausdrücken in Prep finden Sie unter Erstellen von Detailgenauigkeits-, Rang- und Kachelberechnungen.

   3. Erstellen Sie ein Streudiagramm mit dem 1. Bußgeld in Spalten und dem 2. Bußgeld in Zeilen und erstellen Sie eine lineare Trendlinie wie zuvor.

Die Ergebnisse sind identisch mit der Ausgabe mit der nicht pivotierten Datenstruktur.

1. Für die Beantwortung dieser Frage in Tableau Desktop ist die pivotierte Datenstruktur ideal geeignet. Wir müssen lediglich die Fahrer-ID und den Bußgeldbetrag in ein Balkendiagramm überführen. Die Standard-Aggregation lautet bereits SUM, sodass der vom Fahrer gezahlte Gesamtbetrag automatisch dargestellt wird.

Die Ergebnisse sind identisch mit der Ausgabe mit der nicht pivotierten Datenstruktur.

1. Für die Beantwortung dieser Frage in Tableau Desktop ist die pivotierte Datenstruktur ideal geeignet. Wir müssen lediglich die Fahrer-ID und eine Anzahl der Unterschiede für den Verstoßtyp als Balkendiagramm ausgeben und haben somit unsere Antwort.

Die Ergebnisse sind identisch mit der Ausgabe mit der nicht pivotierten Datenstruktur.

1. Um diese Frage in Tableau Desktop zu beantworten, reicht es nicht aus, den Bußgeld-Gesamtbetrag einfach durch zwei zu teilen, da einige Fahrer nur einen Verstoß begangen haben. Wir können auch nicht das durchschnittliche Bußgeld pro Fahrer berechnen und den Durchschnitt dieser Werte verwenden, weil die Durchschnittsbestimmung von Durchschnittswerten zu Inkonsistenzen führen kann. Stattdessen müssen wir den bezahlten Gesamtbetrag von Fahrern berechnen, die nie eine Verkehrsschule besucht haben. Anschließend teilen wir diesen Wert durch die Gesamtzahl Verstöße, die mit diesen Bußgeldern in Verbindung steht.

   1. Zuerst müssen wir bestimmen, ob für die einzelnen Fahrer ein zweiter Verstoß vorliegt. Dabei können wir auf die Tatsache zurückgreifen, dass das Datum des 2. Verstoßes null ist, wenn kein zweiter Verstoß vorliegt, und wir können mit der Erstellung der Berechnung beginnen:

      IFNULL(STR([2nd Infraction Date]), 'no')

      Dadurch wird entweder das Datum des zweiten Verstoßes (sofern vorhanden) oder "nein" zurückgegeben, wenn kein zweiter Verstoß vorlag.

      Hinweis: Der STR-Teil dieser Berechnung wird benötigt, weil für IFNULL der Datentyp in den zugehörigen Argumenten konsistent sein muss. Da für Nullwerte die Zeichenfolge "nein" zurückgegeben werden soll, müssen wir auch das Datum in eine Zeichenfolge konvertieren.

   2. Als Nächstes müssen wir diese Information in die Anzahl Verstöße (1 oder 2) konvertieren. Wenn das Ergebnis unserer Berechnung vom Typ IFNULL "nein" lautet, sollte der Fahrer mit einem Bußgeld markiert werden. Alle anderen Ergebnisse sollen mit zwei Bußgeldern markiert werden. Die Berechnung lautet:

      Anzahl Verstöße =

      IF IFNULL(STR([2nd Infraction Date]), 'no')= 'no' THEN 1 
      ELSE 2 
      END
      

   3. Nun müssen wir den durchschnittlichen Bußgeldbetrag betrachten. Wir verfügen bereits über ein einzelnes Feld für den Bußgeldbetrag. Wir müssen dieses lediglich durch das neue Feld Anzahl Verstöße teilen und dabei beide Felder in SUM einschließen: 

      Durchschnittliches Bußgeld = (SUM([Fine Amount]) / SUM([Number of Infractions])

2. Zudem müssen wir die Fahrer herausfiltern, die eine Verkehrsschule besucht haben. Es sieht so aus, als könnten wir das Feld Verkehrsschule verwenden und nach Verkehrsschule = nein filtern. Dies würde jedoch nach Verstößen filtern, die nicht mit der Verkehrsschule verbunden sind, und nicht nach Fahrern, die nie eine Verkehrsschule besucht haben. Wenn ein Fahrer wegen eines Verstoßes in die Verkehrsschule ging, aber nicht wegen des anderen, soll an dieser Stelle keiner der beiden Verstöße berücksichtigt werden – dieser Fahrer war in der Verkehrsschule und passt daher nicht zu den Parametern der Frage.

   Wir möchten also die Fahrer herausfiltern, die eine Verkehrsschule besucht haben. Hinsichtlich der Daten möchten wir die Fahrer herausfiltern, für die in einer beliebigen Zeile ein "Ja" für Verkehrsschule angezeigt wird (unabhängig davon, mit welchem Verstoß sie verknüpft ist). Wir sollten unsere Berechnung mithilfe einer einfachen Ansicht stufenweise erstellen, um die Ereignisse verfolgen zu können:

   1. Zunächst möchten wir wissen, ob bei einem Fahrer für die Verkehrsschule ein "Ja" angezeigt wird. Ziehen Sie die Fahrer-ID zu Zeilen und Verkehrsschule zu Spalten. Wir erhalten eine Texttabelle mit dem Platzhaltertext "Abc", der die relevanten Werte für die einzelnen Fahrer angibt.

   2. Als Nächstes möchten wir eine Berechnung erstellen, die angibt, ob der Wert für Verkehrsschule "Ja" lautet. Die erste Stufe der Berechnung lautet wie folgt:

      An Verkehrsschule teilgenommen = CONTAINS([Traffic School), 'Yes')

      Wenn wir An Verkehrsschule teilgenommen in den Container Farbe auf der Karte Markierungen verschieben, stellen wir fest, dass die Beschriftung für jede Markierung in der Spalte "Nein" richtigerweise „False" und für alle Markierungen in der Spalte "Ja" richtigerweise "True" lautet.

      

   3. Wir möchten jedoch diese Informationen auf Ebene des Fahrers und nicht auf Ebene des Verstoßes anzeigen. Bei einem Berechnungsversuch eines Ergebnisses mit einer anderen Detailgenauigkeit als der Basisstruktur der Daten liegt die Verwendung eines LOD-Ausdrucks nahe. Wir verwenden dafür einen LOD-Ausdruck vom Typ FIXED . Wir wissen jedoch, dass der Teil mit dem Aggregationsausdruck einer Detailgenauigkeit aggregiert werden muss. Zuvor haben wir MIN verwendet. Ob dies hier funktioniert? Wir ändern die Berechnung wie folgt: 

      An Verkehrsschule teilgenommen = { FIXED [Driver ID] : MIN( CONTAINS([Traffic School], 'Yes'))}

      

      Wenn wir diese Änderung auf die Ansicht anwenden, erreichen wir das Gegenteil von dem, was wir beabsichtigt haben. Fahrer mit einem "Nein" werden durchweg als "False" markiert. Stattdessen möchten wir für jeden Datensatz des jeweiligen Fahrers das "Ja" als "True" anzeigen. Was bewirkt MIN in dieser Situation? Die erste Antwort wird in alphabetischer Reihenfolge ausgewählt, demzufolge ist sie "Nein".

   4. Wie verhält es sich, wenn wir stattdessen MAX verwenden? Würde dadurch die letzte Antwort in alphabetischer Reihenfolge ausgewählt werden? Wir ändern die Berechnung wie folgt: 

      An Verkehrsschule teilgenommen = { FIXED [Driver ID] : MAX ( CONTAINS( [Traffic School], 'Yes') ) }

      

      Jetzt wird es deutlich: Wenn die Daten eines Fahrers ein "Ja" enthalten, werden sie für den Besuch einer Verkehrsschule mit "True" markiert. Dies ist selbst für den Verstoß der Fall, der nicht mit einer Verkehrsschule in Zusammenhang steht.

   5. Wenn wir An Verkehrsschule teilgenommen in den Container Filter verschieben und nur "False" auswählen, bleiben lediglich die Fahrer übrig, die noch nie eine Verkehrsschule besucht haben.

3. Um die ursprüngliche Frage zu beantworten, verschieben wir Durchschnittliches Bußgeld bei aktiviertem Filter in den Container Text auf der Karte Markierungen. Da wir die Aggregationen in die Berechnungen integriert haben, lautet die Aggregation im Feld AGG. Sie lässt sich nicht ändern. Dies entspricht den Erwartungen.

Die Ergebnisse sind identisch mit der Ausgabe mit der nicht pivotierten Datenstruktur.

1. Um diese Frage in Tableau Desktop zu beantworten, verwenden wir erneut die Funktion DATEDIFF . Für diese Funktion sind ein Start- und Enddatum erforderlich. Diese Informationen sind zwar in unseren Daten vorhanden, sie befinden sich jedoch alle in einem Feld. Wir müssen sie herausziehen und in zwei Feldern anordnen. Da wir sicherstellen möchten, dass beide Werte für den Vergleich der einzelne Fahrer zur Verfügung stehen, müssen wir sie auf der Ebene der Fahrer-ID korrigieren.

   1. Wir verwenden die folgende Berechnung, um nach dem Datum des ersten Verstoßes zu suchen:

      1. Verstoß = { FIXED [Driver ID] : MIN ( [Infraction Date] ) } 

   2. Um das Datum des zweiten Verstoßes kümmern wir uns schrittweise.

      1. Zunächst müssen wir die Datumsangaben untersuchen, die größer als das erste Datum sind:

         IF [Infraction Date] > [1st Infraction] THEN [Infraction Date] END

      2. Dadurch erhalten wir jedoch alle Verstöße nach dem ersten, und wir möchten nur den zweiten Verstoß. Es geht also um den kleinsten Wert dieser Datumsangaben. Schließen Sie den gesamten Ausdruck in MIN ein:

         MIN( IF [Infraction] : [1st Infraction] THEN [Infraction Date] END )

      3. Außerdem möchten wir für jeden Fahrer das Datum des zweiten Verstoßes erneut berechnen. Hier kommen LOD-Ausdrücke ins Spiel. Wir nehmen auf Ebene der Fahrer-ID Korrekturen vor:

         2. Verstoß = { FIXED [Driver ID] : MIN ( IF [Infraction Date] > [1st Infraction] THEN [Infraction Date] END ) }

   3. Nun können wir die Berechnung DATEDIFF erstellen:

      Zeit zwischen Verstößen = DATEDIFF('day', [1st Infraction], [2nd Infraction])

Die Ergebnisse sind identisch mit den Ergebnissen, die mit den anderen beiden Datenstrukturen erzielt wurden.

1. Um diese Frage in Tableau Desktop zu beantworten, verwenden wir eine ähnliche Logik wie bei der pivotierten Datenversion dieser Frage. Mithilfe der für Frage 1 erstellten Felder 1. Verstoß und 2. Verstoß bestimmen wir, ob es sich bei einer bestimmten Zeile um den ersten oder zweiten Verstoß handelt. Dann entnehmen wir den Bußgeldbetrag entsprechend.

   1. Wenn lediglich ein Streudiagramm erstellt werden soll, können wir den LOD-Teil überspringen und lediglich eine Berechnung vom Typ IF verwenden:

      1. Bußgeld = IF [1st Infraction] = [Infraction Date] THEN [Fine Amount] END

      2. Bußgeld = IF [2nd Infraction] = [Infraction Date] THEN [Fine Amount] END

   2. Wenn Sie jedoch den Betrag für das erste und zweite Bußgeld für einen einzelnen Fahrer vergleichen und den Unterschied anzeigen möchten, bekommen wir wie bei der ersten Datenstruktur Probleme mit den Nullen. Es kann nicht schaden, diese Berechnungen in einen LOD-Ausdruck vom Typ FIXED einzuschließen. Daher ist es eine gute Ideen, dies von vornherein zu tun:

      1. Bußgeld = { FIXED [Driver ID] : MIN ( IF [1st Infraction] = [Infraction Date] THEN [Fine Amount] END ) }

      2. Bußgeld = {FIXED [Driver ID] : MIN( IF [2ndInfraction] = [Infraction Date] THEN [Fine Amount] END ) }

Die Ergebnisse sind identisch mit den Ergebnissen, die mit den anderen beiden Datenstrukturen erzielt wurden.

1. Um diese Frage in Tableau Desktop zu beantworten, müssen wir zunächst etwas über die reine LOD-Methode wissen. Beide Methoden greifen auf gefilterte Tableau Prep-Datensätze zurück, bei denen es sich nicht um den ersten oder zweiten Verstoß für einen Fahrer handelt. Die LOD-Methode in Tableau Desktop behält alle Datensätze bei. Wenn wir eine Visualisierung von SUMME(Bezahlter Betrag) nach Fahrer-ID erstellen, würde die reine Tableau Desktop-Version demnach höhere Beträge für Fahrer mit mehr als zwei Verstößen anzeigen. Um einen Wert für Bezahlter Gesamtbetrag aus allen Daten zu erhalten, der mit den anderen Methoden übereinstimmt, müssen wir nicht das Originalfeld Bußgeldbetrag verwenden, sondern stattdessen wie bei der ersten Datenstruktur das erste und zweite Bußgeld addieren.

2. Mit den Feldern, die wir für Frage 2 erstellt haben, addieren wir die beiden Bußgeldbeträge. ZN ist notwendig, um ein Nullergebnis für alle Fahrer zu verhindern, die nur einen Verstoß aufweisen. Die Berechnung lautet: 

   Bezahlter Gesamtbetrag = [1st Fine Amount] + ZN([2nd Fine Amount])

Die Ergebnisse sind identisch mit den Ergebnissen, die mit den anderen beiden Datenstrukturen erzielt wurden.

1. Um diese Frage in Tableau Desktop zu beantworten, sind Fahrer-ID und Anzahl der Unterschiede für den Verstoßtyp nicht ausreichend. Da dieser Datensatz Verstöße enthält, die über den zweiten hinausgehen, können für einige Fahrer mehr als zwei Verstoßtypen vorliegen. Um die Ergebnisse den anderen Methoden zuzuordnen, müssen wir den Umfang auf die ersten beiden Verstöße beschränken.

2. Dazu können wir den 1. und 2. Verstoßtyp entnehmen, in LOD-Ausdrücke einschließen, um ihn für den Fahrer auf FIXED festzulegen, und anschließend eine Berechnung vom Typ IF verwenden, um die Typen zu zählen:

   1. 1. Verstoßtyp = { FIXED [Driver ID] : MIN ( IF [1st Infraction] = [Infraction Date] THEN [Infraction Type] END ) }

   2. 2. Verstoßtyp = { FIXED [Driver ID] : MIN ( IF [2nd Infraction] = [Infraction Date] THEN [Infraction Type] END ) }

   3. Anzahl Verstoßtypen =

      IF [1st Infraction Type] = [2nd Infraction Type] THEN 1 
      ELSEIF [1st Infraction Type] != [2nd Infraction Type] THEN 2
      ELSE 1 END 

      Hinweis: Sie können auch mehrere dieser Berechnungen als einzelnes Feld erstellen, indem Sie die ersten Berechnungen direkt in der umfassenderen Berechnung verschachteln. Die kombinierte Berechnung würde hier wie folgt aussehen:
      IF
{FIXED [Driver ID] : MIN(IF [1st Infraction]=[Infraction Date] THEN [Infraction Type] END)}
=
{FIXED [Driver ID] : MIN(IF [2nd Infraction]=[Infraction Date] THEN [Infraction Type] END)}
THEN 1

ELSEIF
{FIXED [Driver ID] : MIN(IF [1st Infraction]=[Infraction Date] THEN [Infraction Type] END)}
!=
{FIXED [Driver ID] : MIN(IF [2nd Infraction]=[Infraction Date] THEN [Infraction Type] END)}
THEN 2

ELSE 1
END
      
      Sie erscheint zwar nicht auf Anhieb sinnvoll, funktioniert jedoch bei Bedarf. (Beachten Sie, dass Zeilenumbrüche und einige Leerzeichen keine Auswirkung darauf haben, wie eine Berechnung von Tableau interpretiert wird.)

3. Wir können den Wert für Anzahl Verstoßtypen anhand der Fahrer-ID darstellen und das Balkendiagramm sortieren.

Die Ergebnisse sind identisch mit den Ergebnissen, die mit den anderen beiden Datenstrukturen erzielt wurden.

1. Um diese Frage in Tableau Desktop zu beantworten, reicht es nicht aus, den Bußgeld-Gesamtbetrag einfach durch zwei zu teilen, da einige Fahrer nur einen Verstoß begangen haben. Wir können auch nicht das durchschnittliche Bußgeld pro Fahrer berechnen und den Durchschnitt dieser Werte verwenden, weil die Durchschnittsbestimmung von Durchschnittswerten zu Inkonsistenzen führen kann. Stattdessen müssen wir den bezahlten Gesamtbetrag von Fahrern berechnen, die nie eine Verkehrsschule besucht haben. Anschließend teilen wir diesen Wert durch die Gesamtzahl Verstöße, die mit diesen Bußgeldern in Verbindung steht.

   1. Zuerst müssen wir bestimmen, ob für die einzelnen Fahrer ein zweiter Verstoß vorliegt. Dabei können wir auf die Tatsache zurückgreifen, dass die Informationen in allen "2." Feldern null sind, wenn kein zweiter Verstoß vorliegt, und wir können mit der Erstellung der Berechnung beginnen.

      IFNULL([2nd Infraction Type], 'no')

      Dies gibt entweder einen Verstoßtyp (sofern vorhanden) oder "nein" zurück, wenn kein zweiter Verstoß vorlag.

   2. Als Nächstes müssen wir diese Information in die Anzahl Verstöße (1 oder 2) konvertieren. Wenn das Ergebnis unserer Berechnung vom Typ IFNULL "nein" lautet, sollte der Fahrer mit einem Bußgeld markiert werden. Alle anderen Ergebnisse sollen mit zwei Bußgeldern markiert werden. Die Berechnung lautet:

      Anzahl Verstöße =

      IF IFNULL([2nd Infraction Type], 'no') = 'no' THEN 1
      ELSE 2
      END

   3. Für die Option "Bezahlter Gesamtbetrag" können wir die Berechnung aus Frage 3 verwenden. Um es auf den Punkt zu bringen, teilen wir diesen Bußgeld-Gesamtwert durch unser neues Feld Anzahl Verstöße, um den durchschnittlichen Bußgeldbetrag zu ermitteln:

      Durchschnittliches Bußgeld = SUM([Total Amount Paid]) / SUM([Number of Infractions])

2. Zudem müssen wir die Fahrer herausfiltern, die eine Verkehrsschule besucht haben. Da dieser Datensatz einige Fahrer mit einem dritten oder vierten Verstoß enthält, können wir nicht dieselbe Methode wie bei der pivotierten Datenstruktur verwenden. Stattdessen wenden wir dieselben Methode wie bei den nicht pivotierten Daten an. Sie wird im Folgenden zusammengefasst:

   1. Zunächst müssen wir zwei Berechnungen erstellen, um zu bestimmen, ob bei dem ersten und zweiten Verstoß eine Verkehrsschule involviert war oder nicht: 

      1. Verkehrsschule = { FIXED [Driver ID] : MIN (IF [1st Infraction] = [Infraction Date] THEN [Traffic School] END ) }

      2. Verkehrsschule = { FIXED [Driver ID] : MIN (IF [2nd Infraction] = [Infraction Date] THEN [Traffic School] END ) }

   2. Anschließend fügen wir diese Werte hinzu, um den Gesamtwert der Besuche einer Verkehrsschule zu ermitteln. 

      Anzahl Besuche einer Verkehrsschule =

      (CASE [1st Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)
      +
      (CASE [2nd Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)

   3. Wenn wir die Anzahl Besuche einer Verkehrsschule in den Bereich Dimensionen des Bereichs Daten ziehen, werden die Werte 0–2 diskret.

   4. Wenn wir nun nach der Anzahl Besuche einer Verkehrsschule filtern, können wir einfach die 0 auswählen und sicher sein, dass wir die Fahrer erhalten, die nie eine Verkehrsschule besucht haben.

3. Um die ursprüngliche Frage zu beantworten, verschieben wir Durchschnittliches Bußgeld in den Container Text auf der Karte Markierungen. Da wir die Aggregationen in die Berechnungen integriert haben, lautet die Aggregation im Feld AGG. Sie lässt sich nicht ändern. Dies entspricht den Erwartungen.

Die Ergebnisse sind identisch mit den Ergebnissen, die mit den anderen beiden Datenstrukturen erzielt wurden.

Fahrerverstöße

• Zeit zwischen Verstößen = DATEDIFF('day', [1st Infraction Date], [2nd Infraction Date])

• Bezahlter Gesamtbetrag = [1st Fine Amount] + ZN([2nd Fine Amount])

• Anzahl Verstoßtypen = IF [1st Infraction Type]=[2nd Infraction Type] THEN 1 ELSEIF [1st Infraction Type]!= [2nd Infraction Type] THEN 2 ELSE 1 END

• Anzahl Verstöße = IF IFNULL([2nd Infraction Type], 'no') = 'no' THEN 1 ELSE 2 END

• Durchschnittliches Bußgeld = ( SUM([1st Fine Amount]) + SUM( ZN([2nd Fine Amount]) ) ) / SUM([Number of Infractions])

• Anzahl Besuche einer Verkehrsschule = (CASE [1st Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END) + (CASE [2nd Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)

Pivotierte Fahrerverstöße

• 1. Verstoß = {FIXED [Driver ID] : MIN(IF [Infraction Number] = "1st" THEN [Infraction Date] END)}

• 2. Verstoß = {FIXED [Driver ID] : MIN(IF [Infraction Number] = "2nd" THEN [Infraction Date] END)}

• Zeit zwischen Verstößen = DATEDIFF('day', [1st Infraction], [2nd Infraction])

• 1. Bußgeld = {FIXED [Driver ID] : MIN( IF [Infraction Number] = "1st" THEN [Fine Amount] END ) }

• Anzahl Verstöße = IF IFNULL(STR([2nd Infraction]), 'no')= 'no' THEN 1 ELSE 2 END

• Durchschnittliches Bußgeld = SUM([Fine Amount])/SUM([Number of Infractions])

• An Verkehrsschule teilgenommen = { FIXED [Driver ID] : MAX( CONTAINS([Traffic School], 'Yes'))}

LOD-Fahrerverstöße

• 1. Verstoß = {FIXED [Driver ID] : MIN([Infraction Date])}

• 2. Verstoß = { FIXED [Driver ID] : MIN( IF [Infraction Date] > [1st Infraction] THEN [Infraction Date] END ) }

• Zeit zwischen Verstößen = DATEDIFF('day', [1st Infraction], [2nd Infraction])

• 1. Bußgeld = {FIXED [Driver ID] : MIN( IF [1st Infraction] = [Infraction Date] THEN [Fine Amount] END ) }

• 2. Bußgeld = {FIXED [Driver ID] : MIN( IF [2nd Infraction] = [Infraction Date] THEN [Fine Amount] END ) }

• Bezahlter Gesamtbetrag = [1st Fine Amount] + ZN([2nd Fine Amount])

• 1. Verstoßtyp = {FIXED [Driver ID] : MIN( IF [1st Infraction] = [Infraction Date] THEN [Infraction Type] END ) }

• 2. Verstoßtyp = {FIXED [Driver ID] : MIN( IF [2nd Infraction] = [Infraction Date] THEN [Infraction Type] END ) }

• Anzahl Verstoßtypen = IF [1st Infraction Type]=[2nd Infraction Type] THEN 1 ELSEIF [1st Infraction Type]!= [2nd Infraction Type] THEN 2 ELSE 1 END

• Anzahl Verstöße = IF IFNULL([2nd Infraction Type], 'no') = 'no' THEN 1 ELSE 2 END

• Durchschnittliches Bußgeld = SUM ([Total Amount Paid]) / SUM([Number of Infractions])

• 1. Verkehrsschule = {FIXED [Driver ID] : MIN (IF [1st Infraction] = [Infraction Date] THEN [Traffic School] END ) }

• 2. Verkehrsschule = {FIXED [Driver ID] : MIN (IF [2nd Infraction] = [Infraction Date] THEN [Traffic School] END ) }

• Anzahl Besuche einer Verkehrsschule = (CASE [1st Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END) + (CASE [2nd Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)