Aide de Tableau Prep

1. Pour répondre à cette question dans Tableau Desktop, nous utilisons la fonction DATEDIFF. Cette fonction prend trois arguments—la partie de date, la date de début et la date de fin. Étant donné que nous souhaitons connaître le nombre de jours entre ces événements, nous allons utiliser la partie de date 'day'. Nos dates de début et de fin figurent dans l’ensemble de données en tant que 1st Infraction Date (Date de la 1ère infraction) et 2nd Infraction Date (Date de la 2nde infraction).

2. Le calcul est le suivant :

   Durée entre les infractions = DATEDIFF('day', [1st Infraction Date], [2nd Infraction Date])

3. Nous pouvons tracer ces données par rapport à Driver ID dans un graphique à barres. Notez que sept conducteurs n’ont pas commis de seconde infraction, donc il y a sept valeurs null.

   

1. Pour répondre à cette question dans Tableau Desktop, nous allons créer un nuage de points de 1st Fine Amount (Montant de la 1ère amende) et 2nd Fine Amount (Montant de la 2nde amende). En déposant Driver ID sur l’étagère Détails dans la fiche Repères, nous pouvons créer un repère pour chaque conducteur.

2. Pour ajouter une courbe de tendance, utilisez l’onglet Analyses dans le volet de gauche et générez une courbe de tendance linéaire. En survolant la courbe de tendance, nous pouvons voir que la valeur R carrée est pratiquement de zéro, et que la valeur p est largement supérieure à un seuil de signification. Nous pouvons déterminer qu’il n’y a pas de corrélation entre le montant de la première et de la seconde amende.

   Si nous utilisions ce nuage de points dans un tableau de bord, il faudrait supprimer la ligne de tendance.

Pour approfondir notre analyse, nous devrons sans doute créer quelques calculs.

1. Pour répondre à ces questions dans Tableau Desktop, nous devons ajouter les amendes des deux infractions à un seul champ. Étant donné que certains conducteurs n’ont pas nécessairement commis de seconde infraction, nous devons utiliser la fonction zéro null ZN pour transformer toute valeur null dans 2nd Fine Amount en zéros. Ne pas le faire entraînera des valeurs null s’il n’y a pas de deuxième amende.

2. Le calcul est le suivant :

   Montant total payé = [1st Fine Amount] + ZN([2nd Fine Amount])

3. Nous pouvons tracer le Montant total payé par rapport à Driver ID et trier le graphique à barres.

1. Pour répondre à cette question dans Tableau Desktop, nous devons créer un calcul plus complexe IF , qui compare si les types de la première et de la seconde infraction sont identiques. S’ils sont identiques, nous attribuons la valeur « 1 ». S’ils sont différents, nous attribuons la valeur « 2 ». Étant donné que nous ne nous soucions que des types d’infractions multiples, tout autre résultat, par exemple un deuxième type d’infraction null, se verra attribuer la valeur « 1 ».

2. Le calcul est le suivant :

   Nombre de types d’infractions =

   IF [1st Infraction Type]=[2nd Infraction Type] THEN 1 
   ELSEIF [1st Infraction Type]!= [2nd Infraction Type] THEN 2 
   ELSE 1 END

3. Nous pouvons tracer le Nombre de types d’infractions par rapport à Driver ID et trier le graphique à barres.

1. Pour répondre à cette question dans Tableau Desktop, nous ne pouvons pas simplement diviser le montant total des amendes par deux, puisque certains conducteurs n’ont commis qu’une seule infraction. Nous ne pouvons pas non plus calculer l’amende moyenne par conducteur et prendre la valeur de ces moyennes, parce que les moyennes de moyennes peuvent générer des incohérences. Au lieu de cela, nous devons calculer le montant total payé par les conducteurs qui n’ont jamais suivi de stage obligatoire, puis diviser par le nombre total d’infractions associées à ces amendes.

   1. Tout d’abord, nous devons déterminer si chaque conducteur a commis une seconde infraction. Nous pouvons utiliser le fait que les informations dans tous les champs « 2nd » seront null s’il n’y a pas eu de seconde infraction et commencer le calcul :

      IFNULL([2nd Infraction Type], 'no')

      Ceci renvoie un type d’infraction, le cas échéant, ou « no » s’il n’y a pas eu de seconde infraction.

   2. Ensuite, nous devons transformer ces informations en nombre d’infractions, 1 ou 2. Si le résultat de notre calcul IFNULL est « no », alors le conducteur doit être marqué comme ayant une seule amende. Tout autre résultat doit entraîner le marquage comme ayant deux amendes. Le calcul est le suivant :

      Nombre d’infractions =

      IF IFNULL([2nd Infraction Type], 'no') = 'no' THEN 1 
      ELSE 2 
      END

   3. Nous devons maintenant considérer le montant total de l’amende. Comme pour la question 3 ci-dessus, nous ajouterons les montants de la première et de la seconde amende, avec une fonction ZN pour la seconde. Toutefois, comme nous souhaitons effectuer le calcul à l’échelle de tout l’ensemble de données, il est recommandé de spécifier les agrégations, SUM, dans le calcul lui-même. Le calcul est le suivant : 

      SUM([1st Fine Amount]) + SUM( ZN([2nd Fine Amount]) )

   4. Pour réunir tous ces éléments, nous prenons le montant total des amendes et nous le divisons par notre nouveau champ calculé Nombre d’infractions pour déterminer le montant moyen de l’amende :

      Montant moyen de l’amende = ( SUM([1st Fine Amount]) + SUM( ZN([2nd Fine Amount]) ) ) / SUM([Number of Infractions])

2. Nous devons également filtrer les conducteurs qui n’ont jamais suivi de stage obligatoire—mais cette information est également stockée sur deux champs différents.

   1. Tableau est très efficace en matière de calculs numériques. Nous formulerons ceci avec des nombres pour obtenir les meilleures performances possibles. Pour combiner ces deux champs, nous créerons un calcul pour chaque champ indiquant « Yes = 1 » et « No = 0 » (la valeur null devrait également = 0 pour les conducteurs n’ayant pas commis de seconde infraction). En totalisant le résultat de ces calculs, tout conducteur ayant une valeur totale de 0 n’a jamais suivi de stage obligatoire (et une valeur de 1 ou 2 indique combien de fois il a suivi ce stage). Nous pouvons ensuite appliquer un filtre de manière à conserver uniquement les conducteurs associés à une valeur de 0.

   2. Cette fois-ci, nous utiliserons une déclaration CASE au lieu de IF. Le fonctionnement est très similaire, mais la syntaxe est différente. Le début du calcul devrait se présenter ainsi :

      CASE [1st Traffic School]
      WHEN 'Yes' THEN 1
      WHEN 'No' THEN 
      ELSE 0
      END

   3. Nous procédons ensuite de même pour le 2nd stage obligatoire. Nous pouvons ajouter les deux éléments dans le même calcul en mettant chaque déclaration de cas entre parenthèses et en ajoutant un signe plus entre eux. En supprimant quelques sauts de ligne, le calcul se présente comme suit :

      Nombre de participations à des stages obligatoires =

      (CASE [1st Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)
      +
      (CASE [2nd Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)
      

   4. Si nous faisons glisser Nombre de participations à des stages obligatoires vers la zone Dimensions du volet Données (au-dessus de la ligne), les valeurs 0-2 deviennent discrètes.

   5. Maintenant si nous appliquons un filtre à Nombre de participations à des stages obligatoires, nous pouvons sélectionner simplement le 0 et savoir que nous obtenons ainsi les conducteurs qui n’ont jamais suivi de stages obligatoires.

3. Pour répondre à la question d’origine, nous pouvons simplement déposer Montant moyen de l’amende sur l’étagère Texte dans la fiche Repères.

   Étant donné que nous avons intégré les agrégations dans le calcul, l’agrégation dans la pile sera AGG et nous ne pouvons pas la modifier, ce qui est attendu.

1. Pour répondre à cette question dans Tableau Desktop, comme nous l’avons fait avec le premier ensemble de données, nous allons utiliser la fonction DATEDIFF . Cette fonction exige une date de début et une date de fin. Cette information est présente dans nos données, mais toutes dans un seul champ. Nous devons l’extraire dans deux champs séparés.

   1. Créez deux champs calculés préliminaires :

      Date de la 1ère infraction = IF [Infraction Number] = "1st" THEN [Infraction Date] END

      Date de la 2nde infraction = IF [Infraction Number] = "2nd" THEN [Infraction Date] END

   2. Nous voulons nous assurer que ces deux valeurs sont disponibles pour être comparées pour chaque conducteur, donc nous devons les corriger au niveau de Driver ID.

      Remarque : vous avez des doutes ? Essayez d’effectuer un calcul DATEDIFF avec ces deux champs en l’état : Durée entre les infractions = DATEDIFF('day', [1st Infraction Date], [2nd Infraction Date])
      Vous obtiendrez des résultats null partout parce que Tableau tente d’effectuer des comparaisons dans une structure de données qui se présente comme ceci :
      
      Ici, la ligne qui sait quelle est la première date ne sait pas quelle est la seconde date, et vice versa. Pour contourner ce problème, nous utiliserons une expression LOD FIXED pour que ces premières et secondes dates soient obligatoirement associées par Driver ID.

   Modifiez chaque calcul comme suit :

   Date de la 1ère infraction = { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "1st" THEN [Infraction Date] END ) }

   Date de la 2nde infraction = { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "2nd" THEN [Infraction Date] END ) }

   Remarque : le calcul d’origine IF doit être agrégé lorsqu’il est intégré dans une expression LOD. Nous pouvons utiliser une agrégation de base qui préservera la valeur de date (des agrégations telles que SUM, AVG ou MIN fonctionneront, mais pas CNT ou CNTD).

   Remarque : ces calculs peuvent également être créés dans Tableau Prep Builder. Pour plus d’informations sur les expressions LOD, consultez Créer des calculs de niveau de détail, de classement et de section.

   3. Nous pouvons maintenant créer le calcul DATEDIFF comme suit :

      Durée entre les infractions = DATEDIFF('day', [1st Infraction Date], [2nd Infraction Date])

      • Pour examiner des semaines ou des mois, modifiez simplement la partie de date (actuellement 'day').

      • Il serait également possible de créer un calcul unique pour l’ensemble du processus en plaçant les calculs FIXED à l’intérieur de DATEDIFF directement : 

        DATEDIFF ( 'day', 
        { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "1st" THEN [Infraction Date] END ) },
        { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "2nd" THEN [Infraction Date] END ) }
        )

   4. Tracez Durée entre les infractions sur les colonnes et Driver ID sur les lignes.

Les résultats seront identiques à la sortie obtenue avec la structure de données non permutées.

1. Pour répondre à cette question dans Tableau Desktop, nous utiliserons une logique très similaire à la question précédente. Nous utiliserons Infraction Number pour identifier si une ligne donnée est la première ou la seconde infraction, puis nous extrairons le montant de l’amende en conséquence.

   1. Si nous souhaitons simplement créer un nuage de points, nous pouvons ignorer la partie LOD et utiliser simplement le calcul IF  :

      Montant de la 1ère amende = IF [Infraction Number] = "1st" THEN [Fine Amount] END

      Montant de la 2nde amende = IF [Infraction Number] = "2nd" THEN [Fine Amount] END

   2. Toutefois, si nous souhaitions comparer et voir la différence de montant entre la première et la seconde amende pour un conducteur spécifique, nous nous heurterions au même problème de valeur null qu’avec les dates. Cela ne peut pas faire de mal d’entourer ces calculs dans une expression LOD FIXED , donc c’est sans doute une bonne idée de procéder ainsi dès le début :

      Montant de la 1ère amende = { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "1st" THEN [Fine Amount] END ) }

      Montant de la 2nde amende = { FIXED [Driver ID] : MIN ( IF [Infraction Number] = "2nd" THEN [Fine Amount] END ) }

      Ces calculs peuvent également être créés dans Tableau Prep Builder. Pour plus d’informations sur les expressions LOD, consultez Créer des calculs de niveau de détail, de classement et de section.

   3. Créez un nuage de points avec Montant de la 1ère amende sur les colonnes et Montant de la 2nde amende sur les lignes, et faites ressortir une courbe de tendance linéaire comme précédemment.

Les résultats seront identiques à la sortie obtenue avec la structure de données non permutées.

1. Pour répondre à cette question dans Tableau Desktop, la structure de données permutées est idéale. Il nous suffit de faire ressortir Driver ID et Fine Amount dans un graphique à barres. L’agrégation par défaut est déjà SUM, donc le montant total payé par le conducteur sera automatiquement tracé.

Les résultats seront identiques à la sortie obtenue avec la structure de données non permutées.

1. Pour répondre à cette question dans Tableau Desktop, la structure de données permutées est idéale. Il nous suffit de faire ressortir Driver ID et un Total distinct de Infraction Type sous forme de graphique à barres et nous aurons notre réponse.

Les résultats seront identiques à la sortie obtenue avec la structure de données non permutées.

1. Pour répondre à cette question dans Tableau Desktop, nous ne pouvons pas simplement diviser le montant total des amendes par deux, puisque certains conducteurs n’ont commis qu’une seule infraction. Nous ne pouvons pas non plus calculer l’amende moyenne par conducteur et prendre la valeur de ces moyennes, parce que les moyennes de moyennes peuvent générer des incohérences. Au lieu de cela, nous devons calculer le montant total payé par les conducteurs qui n’ont jamais suivi de stage obligatoire, puis diviser par le nombre total d’infractions associées à ces amendes.

   1. Tout d’abord, nous devons déterminer si chaque conducteur a commis une seconde infraction. Nous pouvons utiliser le fait que les valeurs dans 2nd Infraction Date seront null s’il n’y a pas eu de seconde infraction et commencer le calcul :

      IFNULL(STR([2nd Infraction Date]), 'no')

      Ceci renvoie la date de la seconde infraction, le cas échéant, ou « no » s’il n’y a pas eu de seconde infraction.

      Remarque : la partie STR de ce calcul est nécessaire parce que IFNULL a besoin de types de données cohérents dans ses arguments. Étant donné que nous souhaitons renvoyer la chaîne « no » pour les valeurs null, nous avons également besoin de convertir la date en une chaîne.

   2. Ensuite, nous devons transformer ces informations en nombre d’infractions, 1 ou 2. Si le résultat de notre calcul IFNULL est « no », alors le conducteur doit être marqué comme ayant une seule amende. Tout autre résultat doit entraîner le marquage comme ayant deux amendes. Le calcul est le suivant :

      Nombre d’infractions =

      IF IFNULL(STR([2nd Infraction Date]), 'no')= 'no' THEN 1 
      ELSE 2 
      END
      

   3. Nous devons maintenant considérer le montant moyen de l’amende. Nous avons déjà un champ unique pour Fine Amount (Montant de l’amende). Il nous suffit de le diviser par notre nouveau champ Number of Infractions (Nombre d’infractions), en entourant les deux dans SUM : 

      Montant moyen de l’amende = (SUM([Fine Amount]) / SUM([Number of Infractions])

2. Nous devons également filtrer les conducteurs qui ont suivi un stage obligatoire. Il semble que nous pourrions utiliser le champ Traffic School et filtrer sur Traffic School = no. Cependant, cela filtrerait les infractions non associées au stage obligatoire et non les conducteurs qui ne sont jamais allés au stage obligatoire. Si un conducteur a suivi un stage obligatoire pour une infraction, mais pas l’autre, nous ne voulons pas que l’une ou l’autre infraction soit prise en compte ici. Ce conducteur a suivi un stage obligatoire et ne correspond donc pas aux paramètres de la question.

   Nous souhaitons simplement filtrer les conducteurs qui ont suivi un stage obligatoire. En termes de données, nous souhaitons filtrer les conducteurs qui affichent une valeur « Yes » pour Traffic School (Stage obligatoire) sur une ligne, quelle que soit l’infraction à laquelle la valeur est associée. Créons notre calcul par étapes, en utilisant une vue simple pour nous aider à suivre ce qui se passe :

   1. Tout d’abord, nous souhaitons savoir si un pilote affiche une valeur « Yes » pour le stage obligatoire. Faites glisser Driver ID vers Lignes et Traffic School vers Colonnes. Nous obtenons un tableau de texte avec le texte d’espace réservé « Abc » qui indique les valeurs pertinentes pour chaque conducteur.

   2. Ensuite, nous souhaitons créer un calcul qui identifie si la valeur de Traffic School est « Yes ». La première étape du calcul est :

      Suivi de stage obligatoire = CONTAINS([Traffic School), 'Yes')

      Si vous déposons Attended Traffic School (Suivi de stage obligatoire) sur l’étagère Couleur dans la fiche Repères, nous voyons clairement les étiquettes « False » pour chaque repère dans la colonne « No », et « True » pour chaque repère dans la colonne « Yes ».

      

   3. Toutefois, ce que nous recherchons en réalité est l’information au niveau du conducteur, non de l’infraction. Une expression LOD est parfaitement adaptée pour tenter de calculer un résultat à un niveau de détail autre que celui de la structure de base des données. Nous allons en faire une expression LOD FIXED . Mais comme vous le savez, la partie de l’expression agrégée d’une LOD doit être agrégée. Nous avions précédemment utilisé MIN. Est-ce que cela va fonctionner dans ce cas ? Nous allons modifier le calcul comme suit : 

      Suivi de stage obligatoire = { FIXED [Driver ID] : MIN( CONTAINS([Traffic School], 'Yes'))}

      

      En appliquant cette modification dans la vue, nous voyons l’opposé de ce que nous recherchons. Tout conducteur associé à une valeur « No » est marqué comme « False » dans le tableau. Au lieu de cela, nous voulons que la valeur « Yes » apparaisse comme « True » pour chaque enregistrement concernant ce conducteur. Que fait la fonction MIN dans ce cas ? Elle prend la première réponse dans l’ordre alphabétique, à savoir « No ».

   4. Et si nous la changions sur MAX ? Prendrait-elle la dernière réponse dans l’ordre alphabétique ? Nous allons modifier le calcul comme suit : 

      Suivi de stage obligatoire = { FIXED [Driver ID] : MAX ( CONTAINS( [Traffic School], 'Yes') ) }

      

      Et voilà ce que nous obtenons : si un conducteur affiche la valeur « Yes » quelque part dans les données, il est marqué comme « True » pour le suivi d’un stage obligatoire, même pour l’infraction n’impliquant pas de stage obligatoire.

   5. Si nous déposons Attended Traffic School sur l’étagère Filtre et que nous sélectionnons simplement « False », nous nous retrouvons seulement avec les conducteurs qui n’ont jamais suivi de stage obligatoire.

3. Pour répondre à la question d’origine, avec notre filtre en place, nous pouvons simplement déposer Average Fine sur l’étagère Texte dans la fiche Repères. Étant donné que nous avons intégré les agrégations dans le calcul, l’agrégation dans le champ sera AGG et nous ne pouvons pas le modifier, ce qui est attendu.

Les résultats seront identiques à la sortie obtenue avec la structure de données non permutées.

1. Pour répondre à cette question dans Tableau Desktop, nous utilisons à nouveau la fonction DATEDIFF . Cette fonction exige une date de début et une date de fin. Cette information est présente dans nos données, mais toutes dans un seul champ. Nous devons l’extraire dans deux champs séparés. Nous voulons nous assurer que ces deux valeurs sont disponibles pour être comparées pour chaque conducteur, donc nous devons les corriger au niveau de Driver ID.

   1. Pour trouver la date de la première infraction, nous utilisons le calcul :

      1ère infraction = { FIXED [Driver ID] : MIN ( [Infraction Date] ) } 

   2. Nous effectuerons le calcul de la date de seconde infraction par étapes.

      1. Pour commencer, nous devons simplement examiner les dates qui sont supérieures à la première date :

         IF [Infraction Date] > [1st Infraction] THEN [Infraction Date] END

      2. Mais ceci nous donnera chaque infraction suivant la première, et nous souhaitons seulement la seconde. Donc nous voulons la plus petite de ces dates. Entourons les données dans MIN :

         MIN( IF [Infraction] : [1st Infraction] THEN [Infraction Date] END )

      3. Nous souhaitons également recalculer la date de la seconde infraction pour chaque conducteur. C’est là qu’interviennent les expressions LOD. Nous ferons la correction nécessaire au niveau de Driver ID :

         2nde infraction = { FIXED [Driver ID] : MIN ( IF [Infraction Date] > [1st Infraction] THEN [Infraction Date] END ) }

   3. Et nous pouvons maintenant créer le calcul DATEDIFF :

      Durée entre les infractions = DATEDIFF('day', [1st Infraction], [2nd Infraction])

Les résultats seront identiques aux sorties obtenues avec les deux autres structures de données.

1. Pour répondre à cette question dans Tableau Desktop, nous utiliserons une logique similaire à la version de données permutées pour cette question. Nous utiliserons les champs 1st Infraction et 2nd Infraction que nous avons créés pour la question I pour identifier si une ligne donnée est la première ou la seconde infraction, puis nous extrairons le montant de l’amende en conséquence.

   1. Si nous souhaitons simplement créer un nuage de points, nous pouvons ignorer la partie LOD et utiliser simplement un calcul IF  :

      Montant de la 1ère amende = IF [1st Infraction] = [Infraction Date] THEN [Fine Amount] END

      Montant de la 2nde amende = IF [2nd Infraction] = [Infraction Date] THEN [Fine Amount] END

   2. Toutefois, si nous souhaitons comparer et voir la différence de montant entre la première et la seconde amende pour un conducteur spécifique, nous nous heurterions au même problème de valeurs null qu’avec la première structure de données. Cela ne peut pas faire de mal d’entourer ces calculs dans une expression LOD FIXED donc c’est sans doute une bonne idée de procéder ainsi dès le début :

      Montant de la 1ère amende = { FIXED [Driver ID] : MIN ( IF [1st Infraction] = [Infraction Date] THEN [Fine Amount] END ) }

      Montant de la 2nde amende = {FIXED [Driver ID] : MIN( IF [2ndInfraction] = [Infraction Date] THEN [Fine Amount] END ) }

Les résultats seront identiques aux sorties obtenues avec les deux autres structures de données.

1. Pour répondre à cette question dans Tableau Desktop, nous devons d’abord prendre conscience d’une caractéristique de la méthode basée sur l’expression LOD seulement. Les deux méthodes utilisant Tableau Prep filtrent les enregistrements qui ne sont pas la première ou la seconde infraction pour un conducteur. La méthode LOD dans Tableau Desktop conserve tous les enregistrements. Cela signifie que si nous devions créer une visualisation SUM(Amount Paid) par Driver ID, la version Tableau Desktop seulement afficherait des montants plus élevés pour les conducteurs ayant commis plus de deux infractions. Pour obtenir une valeur Total Amount Paid (Montant total payé) à partir des données complètes correspondant aux autres méthodes, au lieu d’utiliser le champ Fine Amount (Montant de l’amende) d’origine, nous devons totaliser les premières et secondes amendes comme nous l’avions fait avec la première structure de données.

2. En utilisant les champs que nous avons créés pour la question 2, nous ajouterons les deux montants d’amende. ZN est nécessaire pour éviter un résultat nul pour les conducteurs qui n’ont commis qu’une seule infraction. Le calcul est le suivant : 

   Montant total payé = [1st Fine Amount] + ZN([2nd Fine Amount])

Les résultats seront identiques aux sorties obtenues avec les deux autres structures de données.

1. Pour répondre à cette question dans Tableau Desktop, nous ne pouvons pas nous contenter de faire ressortir Driver ID et un Total distinct pour Infraction Type. Étant donné que cet ensemble de données inclut les infractions au-delà de la seconde, certains conducteurs peuvent être associés à plus de deux types d’infractions. Pour que les résultats correspondent à ceux des autres méthodes, nous devons limiter la portée aux deux premières infractions seulement.

2. Nous pouvons extraire les types de 1ère et 2nde infraction, les entourer dans des expressions LOD pour les rendre FIXED pour le conducteur, et utiliser un calcul IF pour compter les types :

   1. Type de la 1ère infraction = { FIXED [Driver ID] : MIN ( IF [1st Infraction] = [Infraction Date] THEN [Infraction Type] END ) }

   2. Type de la 2nde infraction = { FIXED [Driver ID] : MIN ( IF [2nd Infraction] = [Infraction Date] THEN [Infraction Type] END ) }

   3. Nombre de types d’infractions =

      IF [1st Infraction Type] = [2nd Infraction Type] THEN 1 
      ELSEIF [1st Infraction Type] != [2nd Infraction Type] THEN 2
      ELSE 1 END 

      Remarque : il est également possible de créer un grand nombre de ces calculs en tant que champ unique en imbriquant les calculs initiaux directement dans un calcul plus large. Dans ce cas, le calcul combiné se présenterait ainsi :
      IF
{FIXED [Driver ID] : MIN(IF [1st Infraction]=[Infraction Date] THEN [Infraction Type] END)}
=
{FIXED [Driver ID] : MIN(IF [2nd Infraction]=[Infraction Date] THEN [Infraction Type] END)}
THEN 1

ELSEIF
{FIXED [Driver ID] : MIN(IF [1st Infraction]=[Infraction Date] THEN [Infraction Type] END)}
!=
{FIXED [Driver ID] : MIN(IF [2nd Infraction]=[Infraction Date] THEN [Infraction Type] END)}
THEN 2

ELSE 1
END
      
      Ce qui est un peu difficile à appréhender mais fonctionne si vous avez une préférence pour ce calcul. (Notez que les sauts de ligne et certains espaces n’ont pas d’incidence sur l’interprétation d’un calcul par Tableau.)

3. Nous pouvons tracer le Nombre de types d’infractions par rapport à Driver ID et trier le graphique à barres.

Les résultats seront identiques aux sorties obtenues avec les deux autres structures de données.

1. Pour répondre à cette question dans Tableau Desktop, nous ne pouvons pas simplement diviser le montant total des amendes par deux, puisque certains conducteurs n’ont commis qu’une seule infraction. Nous ne pouvons pas non plus calculer l’amende moyenne par conducteur et prendre la valeur de ces moyennes, parce que les moyennes de moyennes peuvent générer des incohérences. Au lieu de cela, nous devons calculer le montant total payé par les conducteurs qui n’ont jamais suivi de stage obligatoire, puis diviser par le nombre total d’infractions associées à ces amendes.

   1. Tout d’abord, nous devons déterminer si chaque conducteur a commis une seconde infraction. Nous pouvons utiliser le fait que les informations dans tous les champs « 2nd » seront null s’il n’y a pas eu de seconde infraction et commencer le calcul :

      IFNULL([2nd Infraction Type], 'no')

      Ceci renvoie un type d’infraction, le cas échéant, ou « no » s’il n’y a pas eu de seconde infraction.

   2. Ensuite, nous devons transformer ces informations en nombre d’infractions, 1 ou 2. Si le résultat de notre calcul IFNULL est « no », alors le conducteur doit être marqué comme ayant une seule amende. Tout autre résultat doit entraîner le marquage comme ayant deux amendes. Le calcul est le suivant :

      Nombre d’infractions =

      IF IFNULL([2nd Infraction Type], 'no') = 'no' THEN 1
      ELSE 2
      END

   3. Pour le montant total payé, nous pouvons utiliser le calcul de la question 3. Pour réunir tous ces éléments, nous prenons le montant total des amendes et nous le divisons par notre nouveau champ calculé Nombre d’infractions pour déterminer le montant moyen de l’amende :

      Montant moyen de l’amende = SUM([Total Amount Paid]) / SUM([Number of Infractions])

2. Nous devons également filtrer les conducteurs qui ont suivi un stage obligatoire. Étant donné que cet ensemble de données inclut des conducteurs ayant commis une troisième ou une quatrième infraction, nous ne pouvons pas utiliser la même méthode que la structure de données permutées. Au lieu de cela, nous suivrons la même méthode que les données non permutées, résumée ici :

   1. Tout d’abord nous devons créer deux calculs qui identifient si la première et la seconde infractions impliquaient ou non un stage obligatoire : 

      1er stage obligatoire = { FIXED [Driver ID] : MIN (IF [1st Infraction] = [Infraction Date] THEN [Traffic School] END ) }

      2nd stage obligatoire = { FIXED [Driver ID] : MIN (IF [2nd Infraction] = [Infraction Date] THEN [Traffic School] END ) }

   2. Nous additionnerons ces valeurs pour obtenir le nombre total de participations à des stages obligatoires : 

      Nombre de participations à des stages obligatoires =

      (CASE [1st Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)
      +
      (CASE [2nd Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)

   3. Si nous faisons glisser Nombre de participations à des stages obligatoires vers la zone Dimensions du volet Données, les valeurs 0–2 deviennent discrètes.

   4. Maintenant si nous appliquons un filtre à Nombre de participations à des stages obligatoires, nous pouvons sélectionner simplement le 0 et savoir que nous obtenons ainsi les conducteurs qui n’ont jamais suivi de stages obligatoires.

3. Pour répondre à la question d’origine, nous pouvons simplement déposer Montant moyen de l’amende sur l’étagère Texte dans la fiche Repères. Étant donné que nous avons intégré les agrégations dans le calcul, l’agrégation dans le champ sera AGG et nous ne pouvons pas le modifier, ce qui est attendu.

Les résultats seront identiques aux sorties obtenues avec les deux autres structures de données.

Infractions de conducteurs

• Durée entre les infractions = DATEDIFF('day', [1st Infraction Date], [2nd Infraction Date])

• Montant total payé =[1st Fine Amount] + ZN([2nd Fine Amount])

• Nombre de types d’infractions = IF [1st Infraction Type]=[2nd Infraction Type] THEN 1 ELSEIF [1st Infraction Type]!= [2nd Infraction Type] THEN 2 ELSE 1 END

• Nombre d’infractions = IF IFNULL([2nd Infraction Type], 'no') = 'no' THEN 1 ELSE 2 END

• Montant moyen de l’amende = ( SUM([1st Fine Amount]) + SUM( ZN([2nd Fine Amount]) ) ) / SUM([Number of Infractions])

• Nombre de participations à des stages obligatoires = (CASE [1st Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END) + (CASE [2nd Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)

Infractions de conducteur avec données permutées

• 1ère infraction = {FIXED [Driver ID] : MIN(IF [Infraction Number] = "1st" THEN [Infraction Date] END)}

• 2nde infraction = {FIXED [Driver ID] : MIN(IF [Infraction Number] = "2nd" THEN [Infraction Date] END)}

• Durée entre les infractions = DATEDIFF('day', [1st Infraction], [2nd Infraction])

• Montant de la 1ère amende = {FIXED [Driver ID] : MIN( IF [Infraction Number] = "1st" THEN [Fine Amount] END ) }

• Nombre d’infractions = IF IFNULL(STR([2nd Infraction]), 'no')= 'no' THEN 1 ELSE 2 END

• Montant moyen de l’amende = SUM([Fine Amount])/SUM([Number of Infractions])

• Suivi de stage obligatoire = { FIXED [Driver ID] : MAX( CONTAINS([Traffic School], 'Yes'))}

Infractions de conducteurs avec expressions LOD

• 1ère infraction = {FIXED [Driver ID] : MIN([Infraction Date])}

• 2nde infraction = { FIXED [Driver ID] : MIN( IF [Infraction Date] > [1st Infraction] THEN [Infraction Date] END ) }

• Durée entre les infractions = DATEDIFF('day', [1st Infraction], [2nd Infraction])

• Montant de la 1ère amende = {FIXED [Driver ID] : MIN( IF [1st Infraction] = [Infraction Date] THEN [Fine Amount] END ) }

• Montant de la 2nde amende = {FIXED [Driver ID] : MIN( IF [2nd Infraction] = [Infraction Date] THEN [Fine Amount] END ) }

• Montant total payé = [1st Fine Amount] + ZN([2nd Fine Amount])

• Type de la 1ère infraction = {FIXED [Driver ID] : MIN( IF [1st Infraction] = [Infraction Date] THEN [Infraction Type] END ) }

• Type de la 2nde infraction = {FIXED [Driver ID] : MIN( IF [2nd Infraction] = [Infraction Date] THEN [Infraction Type] END ) }

• Nombre de types d’infractions = IF [1st Infraction Type]=[2nd Infraction Type] THEN 1 ELSEIF [1st Infraction Type]!= [2nd Infraction Type] THEN 2 ELSE 1 END

• Nombre d’infractions = IF IFNULL([2nd Infraction Type], 'no') = 'no' THEN 1 ELSE 2 END

• Montant moyen de l’amende = SUM ([Total Amount Paid]) / SUM([Number of Infractions])

• 1er stage obligatoire = {FIXED [Driver ID] : MIN (IF [1st Infraction] = [Infraction Date] THEN [Traffic School] END ) }

• 2nd stage obligatoire = {FIXED [Driver ID] : MIN (IF [2nd Infraction] = [Infraction Date] THEN [Traffic School] END ) }

• Nombre de participations à des stages obligatoires = (CASE [1st Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END) + (CASE [2nd Traffic School] WHEN 'Yes' THEN 1 WHEN 'No' THEN 0 ELSE 0 END)